package
{
	import away3d.cameras.Camera3D;
	import away3d.containers.View3D;
	import away3d.primitives.Cone;
	import away3d.primitives.Cube;
	import away3d.primitives.Sphere;
	
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.ui.Keyboard;
	
	[SWF(width="500", height="400", frameRate="60", backgroundColor="#FFFFFF")]
	public class Basic04Camera3D extends Sprite
	{
		private var cam:Camera3D;
		private var lastKey:uint;
		private var keyIsDown:Boolean = false;
		private var View:View3D;
		private var cover:Cover;
		public function Basic04Camera3D()
		{
			// create a basic camera
			cam = new Camera3D();
			cam.z = -1000; // make sure it's positioned away from the default 0,0,0 coordinate
			
			// create a viewport
			View = new View3D({camera:cam,x:250,y:200});
			addChild(View);
			
			// make some objects and put it on the 3D stage
			var sphere:Sphere = new Sphere({material:"red#black",radius:50});
			View.scene.addChild(sphere);
			var cone:Cone = new Cone({material:"green#black", radius:50, height:100, x:-150});
			View.scene.addChild(cone);
			var cube:Cube = new Cube({material:"blue#black", depth:100, width:100, height:100, x:150});
			View.scene.addChild(cube);
			
			// add a huge surrounding sphere so we really can see what we're doing
			var largeSphere:Sphere = new Sphere({radius:1500,material:"yellow#black"});
			largeSphere.invertFaces();
			View.scene.addChild(largeSphere);
			View.render();
			
			// only run when user is above the SWF
			cover = new Cover(this);
			addChild(cover);
			
			this.stage.addEventListener(KeyboardEvent.KEY_DOWN,onKeyDown);
			this.stage.addEventListener(KeyboardEvent.KEY_UP,onKeyUp);
			this.addEventListener(Event.ENTER_FRAME,onEnterFrame);
		}
		
		private function onEnterFrame(e:Event):void
		{
			if(!cover.visible)
			{
				if(keyIsDown){
					// if the key is still pressed, just keep on moving
					switch(lastKey){
						case 87				: cam.moveUp(10); break;
						case 83				: cam.moveDown(10); break;
						case 65				: cam.moveLeft(10); break;
						case 68				: cam.moveRight(10); break;
						case Keyboard.UP	: cam.moveForward(10); break;
						case Keyboard.DOWN	: cam.moveBackward(10); break;
					}
				}
				// render the view
				View.render();
			}
		}
		private function onKeyDown(e:KeyboardEvent):void
		{
			lastKey = e.keyCode;
			keyIsDown = true;
		}
		private function onKeyUp(e:KeyboardEvent):void
		{
			keyIsDown = false;
		}
	}
}